E131 | E1.31 library for Arduino with ESP8266 support

@ECHO OFF
SETLOCAL enabledelayedexpansion
:: precautions
:: cd /d d:\videos\series
:: if /i not "%cd%"=="d:\videos\series" echo invalid series dir. && exit /b
:: if not exist "pilot episodes" echo pilot episodes dir missing. && exit /b
::if not exist "d:\other\scripts\lootname.cmd" echo lootname missing. && exit /b
(
FOR /f "delims=" %%g IN ('dir /s/b /a-d *.mp4 *.mkv *.m4v *.avi *.flv *.mpg *.mpeg *.mpe *.wmv *.mov *.ts *.m2ts *.vob *.3gp *.rm') DO (
rem CALL d:\other\scripts\lootname.cmd %1 data
 CALL :extract "%%~ng"
 ECHO !name!*%%g
)
)>tempfile.txt
ECHO zzzzzzzzz*zzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzzz>>tempfile.txt
:: File has format extractedname*fullname
SET "lastname="
SET "pilot="

(
FOR /f "tokens=1*delims=*" %%g IN ('sort tempfile.txt') DO (
 IF /i "%%g"=="!lastname!" (
  REM more than one entry with same extractedname
  IF DEFINED pilot (
   REM first episode found - directory to be created
   IF NOT EXIST "%%g" ECHO MD "%cd%\%%g"
   REM move pilot to the directory if required
   IF /i "!pilotdir!" neq "%cd%\%%g\" ECHO MOVE "!pilot!" "%cd%\%%g\"
   REM done with pilot
   SET "pilot="
  )
   IF /i "%%~dph" neq "%cd%\%%g\" ECHO MOVE "%%h" "%cd%\%%g\"
 ) ELSE (
  REM first occurrence of extractedname
  IF DEFINED pilot (
   REM pilot following pilot - only pilot 
   IF /i "!pilotdir!" neq "%cd%\PILOT EPISODES\" ECHO MOVE "!pilot!" "%cd%\PILOT EPISODES\"
  )
  SET "pilot=%%h"
  SET "pilotdir=%%~dph"
  SET "lastname=%%g"
 )
)
)>whattodo.bat
ENDLOCAL
GOTO :eof